source ~/.profile

# Enable Powerlevel10k instant prompt. Should stay close to the top of ~/.config/zsh/.zshrc.
# Initialization code that may require console input (password prompts, [y/n]
# confirmations, etc.) must go above this block; everything else may go below.
if [[ -r "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh" ]]; then
  source "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh"
fi

# Use LS colors for ZSH completion
export LS_COLORS='rs=0:di=01;34:ln=01;36:mh=00:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:mi=00:su=37;41:sg=30;43:ca=30;41:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arc=01;31:*.arj=01;31:*.taz=01;31:*.lha=01;31:*.lz4=01;31:*.lzh=01;31:*.lzma=01;31:*.tlz=01;31:*.txz=01;31:*.tzo=01;31:*.t7z=01;31:*.zip=01;31:*.z=01;31:*.dz=01;31:*.gz=01;31:*.lrz=01;31:*.lz=01;31:*.lzo=01;31:*.xz=01;31:*.zst=01;31:*.tzst=01;31:*.bz2=01;31:*.bz=01;31:*.tbz=01;31:*.tbz2=01;31:*.tz=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.war=01;31:*.ear=01;31:*.sar=01;31:*.rar=01;31:*.alz=01;31:*.ace=01;31:*.zoo=01;31:*.cpio=01;31:*.7z=01;31:*.rz=01;31:*.cab=01;31:*.wim=01;31:*.swm=01;31:*.dwm=01;31:*.esd=01;31:*.jpg=01;35:*.jpeg=01;35:*.mjpg=01;35:*.mjpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.svg=01;35:*.svgz=01;35:*.mng=01;35:*.pcx=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.m2v=01;35:*.mkv=01;35:*.webm=01;35:*.ogm=01;35:*.mp4=01;35:*.m4v=01;35:*.mp4v=01;35:*.vob=01;35:*.qt=01;35:*.nuv=01;35:*.wmv=01;35:*.asf=01;35:*.rm=01;35:*.rmvb=01;35:*.flc=01;35:*.avi=01;35:*.fli=01;35:*.flv=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.yuv=01;35:*.cgm=01;35:*.emf=01;35:*.ogv=01;35:*.ogx=01;35:*.aac=00;36:*.au=00;36:*.flac=00;36:*.m4a=00;36:*.mid=00;36:*.midi=00;36:*.mka=00;36:*.mp3=00;36:*.mpc=00;36:*.ogg=00;36:*.ra=00;36:*.wav=00;36:*.oga=00;36:*.opus=00;36:*.spx=00;36:*.xspf=00;36:'
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' menu select

# Use cd without cd
setopt autocd

# create a zkbd compatible hash;
# to add other keys to this hash, see: man 5 terminfo
typeset -g -A key

# Use vi-mode
source ${XDG_CONFIG_HOME}/zsh/zsh-vi-mode/zsh-vi-mode.plugin.zsh
ZVM_VI_INSERT_ESCAPE_BINDKEY=jj

# Finally, make sure the terminal is in application mode, when zle is
# active. Only then are the values from $terminfo valid.
if (( ${+terminfo[smkx]} && ${+terminfo[rmkx]} )); then
	autoload -Uz add-zle-hook-widget
	function zle_application_mode_start { echoti smkx }
	function zle_application_mode_stop { echoti rmkx }
	add-zle-hook-widget -Uz zle-line-init zle_application_mode_start
	add-zle-hook-widget -Uz zle-line-finish zle_application_mode_stop
fi

function cd_to() {
    setopt localoptions pipefail no_aliases 2> /dev/null
    local dir=$1
    if [[ -z "$dir" ]]; then
        zle redisplay
        return 0
    fi
    zle push-line # Clear buffer. Auto-restored on next prompt.
    cd $dir
    zle accept-line
    local ret=$?
    unset dir # ensure this doesn't end up appearing in prompt expansion
    zle reset-prompt
}

# Use FZY instead of FZF for ctrl-t
function find_global_directories() {
    zle -I
    FZY_CACHE=~/.cache/fzy_paths
    if [ -f $FZY_CACHE ]; then
        # Check if cache is older than 1 day
        if [ $(($(date +%s) - $(date -r $FZY_CACHE +%s))) -gt 86400 ]; then
            rm $FZY_CACHE
        fi
    fi
    if [ ! -f $FZY_CACHE ]; then
        PATHS="$(/usr/bin/git --git-dir=$HOME/.dotfiles/ --work-tree=$HOME ls-files | xargs -n 1 dirname | uniq | grep -v '^\.$' | parallel echo ~/{})"
        search_dirs=( \
            ~/Workspace/ \
            /home/server/Storage/Thomas/ \
        )
        for i in $search_dirs ; do
            if [ -d $i ]; then
                PATHS="$PATHS\n$i"
                PATHS="$PATHS\n$(fdfind . $i -t d -d 8)"
            fi
        done
        echo -e $PATHS > $FZY_CACHE
    fi
    cd_to "$(cat $FZY_CACHE | fzy -l 20)"
}

function find_local_directories() {
    zle -I
    cd_to "$(fd . -t d | fzy -l 20)"
}

function edit_local_files() {
    zle -I
    file=$(fd . -t f | fzy -l 20)
    if [ -z "$file" ]; then
        return 0
    fi
    nvim "$file"
}

function edit_global_files() {
    zle -I
    FZY_CACHE=~/.cache/fzy_file_paths
    if [ -f $FZY_CACHE ]; then
        # Check if cache is older than 1 day
        if [ $(($(date +%s) - $(date -r $FZY_CACHE +%s))) -gt 86400 ]; then
            rm $FZY_CACHE
        fi
    fi
    if [ ! -f $FZY_CACHE ]; then
        PATHS="$(/usr/bin/git --git-dir=$HOME/.dotfiles/ --work-tree=$HOME ls-files | parallel echo ~/{})"
        search_dirs=(~/Workspace/ )
        for i in $search_dirs ; do
            if [ -d $i ]; then
                PATHS="$PATHS\n$(fdfind . $i -t f)"
            fi
        done
        echo -e $PATHS > $FZY_CACHE
    fi
    file=$(cat $FZY_CACHE | fzy -l 20)
    if [ -z "$file" ]; then
        return 0
    fi
    cd_to "$(dirname $file)"
    nvim "$file"

}

function zvm_after_init() {
    key[Home]="${terminfo[khome]}"
    key[End]="${terminfo[kend]}"
    key[Insert]="${terminfo[kich1]}"
    key[Backspace]="${terminfo[kbs]}"
    key[Delete]="${terminfo[kdch1]}"
    key[Up]="${terminfo[kcuu1]}"
    key[Down]="${terminfo[kcud1]}"
    key[Left]="${terminfo[kcub1]}"
    key[Right]="${terminfo[kcuf1]}"
    key[PageUp]="${terminfo[kpp]}"
    key[PageDown]="${terminfo[knp]}"
    key[Shift-Tab]="${terminfo[kcbt]}"

    # setup key accordingly
    [[ -n "${key[Home]}"      ]] && bindkey -- "${key[Home]}"       beginning-of-line
    [[ -n "${key[End]}"       ]] && bindkey -- "${key[End]}"        end-of-line
    [[ -n "${key[Insert]}"    ]] && bindkey -- "${key[Insert]}"     overwrite-mode
    [[ -n "${key[Backspace]}" ]] && bindkey -- "${key[Backspace]}"  backward-delete-char
    [[ -n "${key[Delete]}"    ]] && bindkey -- "${key[Delete]}"     delete-char
    [[ -n "${key[Up]}"        ]] && bindkey -- "${key[Up]}"         up-line-or-history
    [[ -n "${key[Down]}"      ]] && bindkey -- "${key[Down]}"       down-line-or-history
    [[ -n "${key[Left]}"      ]] && bindkey -- "${key[Left]}"       backward-char
    [[ -n "${key[Right]}"     ]] && bindkey -- "${key[Right]}"      forward-char
    [[ -n "${key[PageUp]}"    ]] && bindkey -- "${key[PageUp]}"     beginning-of-buffer-or-history
    [[ -n "${key[PageDown]}"  ]] && bindkey -- "${key[PageDown]}"   end-of-buffer-or-history
    [[ -n "${key[Shift-Tab]}" ]] && bindkey -- "${key[Shift-Tab]}"  reverse-menu-complete

    autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
    zle -N up-line-or-beginning-search
    zle -N down-line-or-beginning-search
    [[ -n "${key[Up]}"   ]] && bindkey -- "${key[Up]}"   up-line-or-beginning-search
    [[ -n "${key[Down]}" ]] && bindkey -- "${key[Down]}" down-line-or-beginning-search


    if [ -f "/usr/share/doc/pkgfile/command-not-found.zsh" ]; then
        source /usr/share/doc/pkgfile/command-not-found.zsh
    fi

    #FZF
    if [ -f "/usr/share/doc/fzf/examples/key-bindings.zsh" ]; then
        source /usr/share/doc/fzf/examples/key-bindings.zsh
        source /usr/share/doc/fzf/examples/completion.zsh
    elif [ -f "/usr/share/fzf/key-bindings.zsh" ]; then
        source /usr/share/fzf/key-bindings.zsh
        source  /usr/share/fzf/completion.zsh
    fi

    if [ -f "/usr/share/zsh/plugins/zsh-autosuggestions/zsh-autosuggestions.zsh" ]; then
        source /usr/share/zsh/plugins/zsh-autosuggestions/zsh-autosuggestions.zsh
    fi

    zle -N find_global_directories
    zle -N find_local_directories
    zle -N edit_global_files
    zle -N edit_local_files

    bindkey "^T" find_global_directories
    bindkey -M emacs "^T" find_global_directories
    bindkey -M vicmd "^T" find_global_directories
    bindkey -M viins "^T" find_global_directories

    bindkey "^Y" find_local_directories
    bindkey -M emacs "^Y" find_local_directories
    bindkey -M vicmd "^Y" find_local_directories
    bindkey -M viins "^Y" find_local_directories

    bindkey "^E" edit_global_files
    bindkey -M emacs "^E" edit_global_files
    bindkey -M vicmd "^E" edit_global_files
    bindkey -M viins "^E" edit_global_files

    bindkey "^W" edit_global_files
    bindkey -M emacs "^W" edit_local_files
    bindkey -M vicmd "^W" edit_local_files
    bindkey -M viins "^W" edit_local_files


    if [ "$SSH_SESSION_ID" != "" ]; then
        mkdir -p /tmp/ssh_sessions
        echo $$ > /tmp/ssh_sessions/"$SSH_SESSION_ID"
    fi
    if [ "$REMOTE_PATH" != "" ]; then
        if [ -d "$REMOTE_PATH" ]; then
            cd "$REMOTE_PATH"
        fi
    elif [ "$PREVIOUS_SESSION_ID" != "" ]; then
        cd "$(readlink -e /proc/$(cat /tmp/ssh_sessions/$PREVIOUS_SESSION_ID)/cwd)"
    fi
}

zstyle ':completion:*' matcher-list '' 'm:{a-zA-Z}={A-Za-z}' 'r:|=*' 'l:|=* r:|=*'
zstyle ':completion::complete:*' gain-privileges 1
zstyle ':completion:*' rehash true


autoload -Uz compinit
compinit -d "$XDG_CACHE_HOME"/zsh/zcompdump-"$ZSH_VERSION"


export HISTFILE="$XDG_STATE_HOME"/zsh/history
export HISTSIZE=10000000
export SAVEHIST=10000000

source $XDG_CONFIG_HOME/zsh/powerlevel10k/powerlevel10k.zsh-theme

# To customize prompt, run `p10k configure` or edit ~/.config/zsh/.p10k.zsh.
[[ ! -f ~/.config/zsh/.p10k.zsh ]] || source ~/.config/zsh/.p10k.zsh

unsetopt share_history

BROWSER=/usr/bin/firefox

# Add bash aliases.
if [ -f ~/.bash_aliases ]; then
    source ~/.bash_aliases
fi

# GPULab
export GPULAB_CERT="$XDG_DATA_HOME/gpulab.pem"
export GPULAB_DEV='False'

# Smartcd
export SMARTCD_QUIET=1
source ~/.smartcd_config

export GCC_COLORS='error=01;31:warning=01;35:note=01;36:caret=01;32:locus=01:quote=01'
export EDITOR=nvim
export LANG=en_US.UTF-8
export ARCHFLAGS="-arch x86_64"
export SSH_KEY_PATH="~/.ssh/rsa_id"
export PYTHONDONTWRITEBYTECODE=1
export TERM="screen-256color"
export PATH=$HOME/.local/bin:$PATH
export GOPATH=/tmp/go

if command -v micromamba &> /dev/null; then
    eval "$(micromamba shell hook --shell zsh)"
    export MAMBA_ROOT_PREFIX="$HOME/.micromamba";
fi

autoload -Uz add-zsh-hook

eval "$(zoxide init zsh --cmd j)"

function xterm_title_precmd () {
    print -Pn -- '\e]2;%n@%m %~\a'
}

function xterm_title_preexec () {
	print -Pn -- '\e]2;' && print -n -- "${(q)1}\a"
}


if [[ "$TERM" == (Eterm*|alacritty*|aterm*|gnome*|konsole*|kterm*|putty*|rxvt*|screen*|tmux*|xterm*) ]]; then
	add-zsh-hook -Uz precmd xterm_title_precmd
	add-zsh-hook -Uz preexec xterm_title_preexec
fi


###########################################
# Aliases
###########################################

if [[ "$(hostname)" == "mallorea" ]]; then
    alias lf="/usr/bin/lf -last-dir-path /tmp/lf_dir && cd \"\$(cat /tmp/lf_dir 2> /dev/null || pwd)\""
else
    alias lf="cd \"\$(/usr/bin/lf -print-selection -print-last-dir)\""
fi

if command -v fdfind &> /dev/null; then
    alias fd="fdfind"
fi
function o () {
	xdg-open "$1" &!
}

function run_waypipe() {
    SSH_SESSION_ID=$RANDOM
    REMOTE_PATH=$(echo $(pwd) | sed "s|/home/[a-z]*|\$HOME|g")
    SSH_SESSION_ID=$SSH_SESSION_ID waypipe ssh -t $1 env REMOTE_PATH=\"$REMOTE_PATH\" SSH_SESSION_ID=$SSH_SESSION_ID "zsh --login"
}

function git() {
    if [ "$HOME" = "$(pwd)" ]; then
        /usr/bin/git --git-dir="$HOME/.dotfiles/" --work-tree="$HOME" "$@"
    else
        /usr/bin/git "$@"
    fi
}

alias mallorea="run_waypipe mallorea"
alias vault="run_waypipe vault"
alias riva="run_waypipe riva"
alias kell="run_waypipe kell"

alias ls="ls --color=auto"
alias gdb='gdb -q'
alias ll='ls -lhat'
alias compress="tar --use-compress-program=lbzip2 -cvf"
alias vim="nvim"
alias dot='/usr/bin/git --git-dir="$HOME/.dotfiles/" --work-tree="$HOME" "$@"'
alias wget=wget --hsts-file="$XDG_DATA_HOME/wget-hsts"
alias python=python3
alias v="nvim -c ':lua require(\"oil\").open()' && cd \"\$(cat /tmp/oil_dir 2> /dev/null || pwd)\""
alias cpr="rsync --archive -hh --partial --info=stats1,progress2 --modify-window=1"
alias mvr="rsync --archive -hh --partial --info=stats1,progress2 --modify-window=1 --remove-source-files"
alias rg="rg -i --colors 'match:bg:yellow' --colors 'match:fg:black' --colors 'match:style:nobold' --colors 'path:fg:green' --colors 'path:style:bold' --colors 'line:fg:yellow' --colors 'line:style:bold'"
alias ag="rg -i --colors 'match:bg:yellow' --colors 'match:fg:black' --colors 'match:style:nobold' --colors 'path:fg:green' --colors 'path:style:bold' --colors 'line:fg:yellow' --colors 'line:style:bold'"
alias push="git add -A && git commit -m '`date`' && git push"
alias reset="tput reset"